home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / CAPTANCE.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1997-02-22  |  3.7 KB  |  124 lines
  1. 10  'CAPTANCE - Capacitance Calculator - 08 JAN 93 rev. 22 FEB 97
  2. 20  IF EX$=""THEN EX$="EXIT"
  3. 30  CLS:KEY OFF
  4. 40  VIEW PRINT
  5. 50  COLOR 7,0,1
  6. 60  DIM DK$(20,3)
  7. 70  UL$=STRING$(80,205)
  8. 80  U$="###,###.###"
  9. 90  U1$="#######"
  10. 100  '.....read data
  11. 110  FOR Z=1 TO 20
  12. 120   FOR Y=1 TO 3:READ DK$(Z,Y):NEXT Y
  13. 130  NEXT Z
  14. 140  '
  15. 150  '.....start
  16. 160  CLS
  17. 170  PRINT "     DIELECTRIC MATERIAL   ";TAB(29);" CONSTANT (K) ";
  18. 180  PRINT TAB(43);" PUNCTURE VOLTAGE per .001";CHR$(34);" thickness ";
  19. 190  '
  20. 200  '.....print reference table
  21. 210  FOR Z=1 TO 20
  22. 220   DOT$=STRING$(26-LEN(DK$(Z,1)),".")+" "
  23. 230   PRINT " <";CHR$(96+Z);"> ";
  24. 240   PRINT DK$(Z,1);DOT$;DK$(Z,2);TAB(45);DK$(Z,3)
  25. 250  NEXT Z
  26. 260  PRINT UL$;
  27. 270  COLOR 0,7:LOCATE CSRLIN,22
  28. 280  PRINT " Press 1 to continue or 0 to EXIT....."
  29. 290  COLOR 7,0
  30. 300  Z$=INKEY$:IF Z$=""THEN 300
  31. 310  IF Z$="0"THEN CLS:RUN EX$
  32. 320  IF Z$="1"THEN 340
  33. 330  GOTO 300
  34. 340  LOCATE CSRLIN-1:PRINT STRING$(80,32);:LOCATE CSRLIN-1
  35. 350  '
  36. 360  '.....inputs
  37. 370  PRINT " Press <ENTER> if the data requested below is what you are ";
  38. 380  PRINT "seeking, or"
  39. 390  VIEW PRINT 24 TO 24
  40. 400  COLOR 0,7
  41. 410  IF C=0 THEN INPUT" ENTER Capacitance in pF...............................";C
  42. 420  GOSUB 630
  43. 430  '
  44. 440  IF K THEN 560
  45. 450  INPUT " ENTER Letter in < > in above table to select dielectric......";Z$
  46. 460  IF Z$=""THEN 540
  47. 470  IF Z$="t"THEN 510
  48. 480  Z=ASC(Z$)-96:MATL$=DK$(Z,1):K=VAL(DK$(Z,2)):PV=VAL(DK$(Z,3))
  49. 490  GOTO 540
  50. 500  '
  51. 510  INPUT" ENTER Name of dielectric material between plates......";MATL$
  52. 520  INPUT" ENTER K Constant of dielectric material...............";K
  53. 530  INPUT" ENTER Puncture voltage (if known).....................";PV
  54. 540  GOSUB 630
  55. 550  '
  56. 560  IF A=0 THEN INPUT" ENTER Sq.inches of area common to adjacent plates.....";A
  57. 570  GOSUB 630
  58. 580  IF N=0 THEN INPUT" ENTER Number of plates................................";N
  59. 590  GOSUB 630
  60. 600  IF D=0 THEN INPUT" ENTER Separation of adjacent plates in inches.........";D
  61. 610  GOSUB 630
  62. 620  GOTO 390
  63. 630  '.....compute unknown factor
  64. 640  COLOR 7,0:CLS
  65. 650  J=0.2248
  66. 660  IF K*A*N*D THEN C=J*K*A*(N-1)/D:GOTO 710
  67. 670  IF C*A*N*D THEN K=C/J/A/(N-1)*D:GOTO 710
  68. 680  IF C*K*N*D THEN A=C/J/K/(N-1)*D:GOTO 710
  69. 690  IF C*K*A*D THEN X=C/J/K/A*D:N=X+1:GOTO 710
  70. 700  IF C*K*A*N THEN D=J*K*A*(N-1)/C:GOTO 710
  71. 710  IF C*K*A*N*D THEN 750
  72. 720  COLOR 0,7
  73. 730  RETURN
  74. 740  '
  75. 750  '.....print results
  76. 760  VIEW PRINT
  77. 770  CLS:COLOR 7,0
  78. 780  INPUT " ENTER thickness of plates (inches).............";T
  79. 790  CLS:COLOR 15,2
  80. 800  PRINT " CAPACITOR DESIGN PARAMETERS ";TAB(57);"by George Murphy VE3ERP ";
  81. 810  COLOR 1,0:PRINT STRING$(80,223);
  82. 820  COLOR 7,0
  83. 830  PRINT" Dielectric .........................";" ";MATL$
  84. 840  PRINT" Dielectric constant.................";USING U$;K
  85. 850  IF PV=0 THEN 880
  86. 860  PRINT" Puncture voltage....................";USING U$;D*1000*PV;
  87. 870  PRINT " volts"
  88. 880  PRINT" Area common to adjacent plates......";USING U$;A;:PRINT " sq.in."
  89. 890  IF INT(N)=N THEN N$=U1$ ELSE N$=U$
  90. 900  PRINT" Number of plates....................";USING N$;N
  91. 910  PRINT" Distance between plates.............";USING U$;D;:PRINT " in."
  92. 920  PRINT" Thickness of plates.................";USING U$;T;:PRINT " in."
  93. 930  S=CINT(N)*T+(D*(N-1))
  94. 940  PRINT" Thickness overall...................";USING U$;S;:PRINT " in."
  95. 950  PRINT" Capacitance.........................";USING U$;C;:PRINT " pF"
  96. 960  PRINT UL$;
  97. 970  LN=CSRLIN-1:GOSUB 1110
  98. 980  MATL$="":C=0:K=0:PV=0:A=0:N=0:D=0:T=0:S=0
  99. 990  GOTO 150
  100. 1000  '
  101. 1010  DATA Air,1.0,21,Alsimag 196,5.7,240,Bakelite,4.4-5.4,300
  102. 1020  DATA Bakelite (mica filled),4.7,325-375, Cellulose acetate,3.3-3.9,250-600
  103. 1030  DATA Fibre,5-7.5,150-180,Formica,4.6-4.9,450,Glass (window),7.6-8,200-250
  104. 1040  DATA Glass (Pyrex),4.8,335,Mica (ruby),5.4,2800-5600,Mycalex,7.4,250
  105. 1050  DATA Paper (Royal grey),3,200,Plexiglas,2.8,990,Polyethylene,2.3,1200
  106. 1060  DATA Polystyrene,2.6,500-700,Porcelain,5.1-5.9,40-100
  107. 1070  DATA Quartz (fused),3.8,1000,Steatite (low loss),5.8,150-315
  108. 1080  DATA Teflon,2.1,1000-2000,OTHER," "," "
  109. 1090  END
  110. 1100  '
  111. 1110  'HARDCOPY
  112. 1120  GOSUB 1230:LOCATE 25,2:COLOR 14,6
  113. 1130  PRINT " Press 1 to print screen, 2 to print screen & ";
  114. 1140  PRINT "advance paper, or 3 to continue.";:COLOR 7,0
  115. 1150  Z$=INKEY$:IF Z$="3"THEN GOSUB 1230:RETURN
  116. 1160  IF Z$="1"OR Z$="2"THEN GOSUB 1230:GOTO 1180
  117. 1170  GOTO 1150
  118. 1180  FOR QX=1 TO 24:FOR QY=1 TO 80
  119. 1190  LPRINT CHR$(SCREEN(QX,QY));
  120. 1200  NEXT QY:NEXT QX
  121. 1210  IF Z$="2"THEN LPRINT CHR$(12)
  122. 1220  GOTO 1120
  123. 1230  LOCATE 25,1:PRINT STRING$(80,32);:RETURN
  124.